home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Languguage OS 2
/
Languguage OS II Version 10-94 (Knowledge Media)(1994).ISO
/
gnu
/
elispman.lha
/
elispman
/
elisp-10
(
.txt
)
< prev
next >
Wrap
GNU Info File
|
1993-06-01
|
50KB
|
955 lines
This is Info file elisp, produced by Makeinfo-1.55 from the input file
elisp.texi.
This is edition 2.0 of the GNU Emacs Lisp Reference Manual, for
Emacs Version 19.
Published by the Free Software Foundation, 675 Massachusetts Avenue,
Cambridge, MA 02139 USA
Copyright (C) 1990, 1991, 1992, 1993 Free Software Foundation, Inc.
Permission is granted to make and distribute verbatim copies of this
manual provided the copyright notice and this permission notice are
preserved on all copies.
Permission is granted to copy and distribute modified versions of
this manual under the conditions for verbatim copying, provided that
the entire resulting derived work is distributed under the terms of a
permission notice identical to this one.
Permission is granted to copy and distribute translations of this
manual into another language, under the above conditions for modified
versions, except that this permission notice may be stated in a
translation approved by the Foundation.
File: elisp, Node: Features, Next: Unloading, Prev: Repeated Loading, Up: Loading
Features
========
`provide' and `require' are an alternative to `autoload' for loading
files automatically. They work in terms of named "features".
Autoloading is triggered by calling a specific function, but a feature
is loaded the first time another program asks for it by name.
The use of named features simplifies the task of determining whether
required definitions have been defined. A feature name is a symbol that
stands for a collection of functions, variables, etc. A program that
needs the collection may ensure that they are defined by "requiring"
the feature. If the file that contains the feature has not yet been
loaded, then it will be loaded (or an error will be signaled if it
cannot be loaded). The file thus loaded must "provide" the required
feature or an error will be signaled.
To require the presence of a feature, call `require' with the
feature name as argument. `require' looks in the global variable
`features' to see whether the desired feature has been provided
already. If not, it loads the feature from the appropriate file. This
file should call `provide' at the top-level to add the feature to
`features'.
Features are normally named after the files they are provided in so
that `require' need not be given the file name.
For example, in `emacs/lisp/prolog.el', the definition for
`run-prolog' includes the following code:
(defun run-prolog ()
"Run an inferior Prolog process,\
input and output via buffer *prolog*."
(interactive)
(require 'comint)
(switch-to-buffer (make-comint "prolog" prolog-program-name))
(inferior-prolog-mode))
The expression `(require 'shell)' loads the file `shell.el' if it has
not yet been loaded. This ensures that `make-shell' is defined.
The `shell.el' file contains the following top-level expression:
(provide 'shell)
This adds `shell' to the global `features' list when the `shell' file
is loaded, so that `(require 'shell)' will henceforth know that nothing
needs to be done.
When `require' is used at top-level in a file, it takes effect if
you byte-compile that file (*note Byte Compilation::.). This is in case
the required package contains macros that the byte compiler must know
about.
Although top-level calls to `require' are evaluated during byte
compilation, `provide' calls are not. Therefore, you can ensure that a
file of definitions is loaded before it is byte-compiled by including a
`provide' followed by a `require' for the same feature, as in the
following example.
(provide 'my-feature) ; Ignored by byte compiler,
; evaluated by `load'.
(require 'my-feature) ; Evaluated by byte compiler.
- Function: provide FEATURE
This function announces that FEATURE is now loaded, or being
loaded, into the current Emacs session. This means that the
facilities associated with FEATURE are or will be available for
other Lisp programs.
The direct effect of calling `provide' is to add FEATURE to the
front of the list `features' if it is not already in the list.
The argument FEATURE must be a symbol. `provide' returns FEATURE.
features
=> (bar bish)
(provide 'foo)
=> foo
features
=> (foo bar bish)
During autoloading, if the file is not completely loaded (due to an
error in the evaluation of the contents) any function definitions
or `provide' calls that occurred during the load are undone.
*Note Autoload::.
- Function: require FEATURE &optional FILENAME
This function checks whether FEATURE is present in the current
Emacs session (using `(featurep FEATURE)'; see below). If it is
not, then `require' loads FILENAME with `load'. If FILENAME is
not supplied, then the name of the symbol FEATURE is used as the
file name to load.
If FEATURE is not provided after the file has been loaded, Emacs
will signal the error `error' (with data `Required feature FEATURE
was not provided').
- Function: featurep FEATURE
This function returns `t' if FEATURE has been provided in the
current Emacs session (i.e., FEATURE is a member of `features'.)
- Variable: features
The value of this variable is a list of symbols that are the
features loaded in the current Emacs session. Each symbol was put
in this list with a call to `provide'. The order of the elements
in the `features' list is not significant.
File: elisp, Node: Unloading, Next: Hooks for Loading, Prev: Features, Up: Loading
Unloading
=========
You can discard the functions and variables loaded by a library to
reclaim memory for other Lisp objects. To do this, use the function
`unload-feature':
- Command: unload-feature FEATURE
This command unloads the library that provided feature FEATURE.
It undefines all functions and variables defined with `defvar',
`defmacro', `defconst', `defsubst' and `defalias' by the library
which provided feature FEATURE. It then restores any autoloads
associated with those symbols.
The `unload-feature' function is written in Lisp; its actions are
based on the variable `load-history'.
- Variable: load-history
This variable's value is an alist connecting library names with the
names of functions and variables they define, the features they
provide, and the features they require.
Each element is a list and describes one library. The CAR of the
list is the name of the library, as a string. The rest of the
list is composed of these kinds of objects:
* Symbols, which were defined as functions or variables.
* Lists of the form `(require . FEATURE)' indicating the
features that are required.
* Lists of the form `(provide . FEATURE)' indicating the
features that are provided.
The value of `load-history' may have one element whose CAR is
`nil'. This element describes definitions made with `eval-buffer'
on a buffer that is not visiting a file.
The command `eval-region' updates `load-history', but does so by
adding the symbols defined to the element for the file being visited,
rather than replacing that element.
File: elisp, Node: Hooks for Loading, Prev: Unloading, Up: Loading
Hooks for Loading
=================
You can ask for code to be executed if and when a particular library
is loaded, by calling `eval-after-load'.
- Function: eval-after-load LIBRARY FORM
This function arranges to evaluate FORM at the end of loading the
library LIBRARY, if and when LIBRARY is loaded.
The library name LIBRARY must exactly match the argument of
`load'. To get the proper results when an installed library is
found by searching `load-path', you should not include any
directory names in LIBRARY.
An error in FORM does not undo the load, but does prevent
execution of the rest of FORM.
- Variable: after-load-alist
An alist of expressions to evaluate if and when particular
libraries are loaded. Each element looks like this:
(FILENAME FORMS...)
The function `load' checks `after-load-alist' in order to
implement `eval-after-load'.
File: elisp, Node: Byte Compilation, Next: Debugging, Prev: Loading, Up: Top
Byte Compilation
****************
GNU Emacs Lisp has a "compiler" that translates functions written in
Lisp into a special representation called "byte-code" that can be
executed more efficiently. The compiler replaces Lisp function
definitions with byte-code. When a byte-code function is called, its
definition is evaluated by the "byte-code interpreter".
Because the byte-compiled code is evaluated by the byte-code
interpreter, instead of being executed directly by the machine's
hardware (as true compiled code is), byte-code is completely
transportable from machine to machine without recompilation. It is not,
however, as fast as true compiled code.
In general, any version of Emacs can run byte-compiled code produced
by recent earlier versions of Emacs, but the reverse is not true. In
particular, if you compile a program with Emacs 18, you can run the
compiled code in Emacs 19, but not vice versa.
*Note Compilation Errors::, for how to investigate errors occurring
in byte compilation.
* Menu:
* Compilation Functions:: Byte compilation functions.
* Eval During Compile:: Code to be evaluated when you compile.
* Byte-Code Objects:: The data type used for byte-compiled functions.
* Disassembly:: Disassembling byte-code; how to read byte-code.
File: elisp, Node: Compilation Functions, Next: Eval During Compile, Up: Byte Compilation
The Compilation Functions
=========================
You can byte-compile an individual function or macro definition with
the `byte-compile' function. You can compile a whole file with
`byte-compile-file', or several files with `byte-recompile-directory'
or `batch-byte-compile'.
When you run the byte compiler, you may get warnings in a buffer
called `*Compile-Log*'. These report usage in your program that
suggest a problem, but are not necessarily erroneous.
Be careful when byte-compiling code that uses macros. Macro calls
are expanded when they are compiled, so the macros must already be
defined for proper compilation. For more details, see *Note Compiling
Macros::.
While byte-compiling a file, any `require' calls at top-level are
executed. One way to ensure that necessary macro definitions are
available during compilation is to require the file that defines them.
*Note Features::.
A byte-compiled function is not as efficient as a primitive function
written in C, but runs much faster than the version written in Lisp.
For a rough comparison, consider the example below:
(defun silly-loop (n)
"Return time before and after N iterations of a loop."
(let ((t1 (current-time-string)))
(while (> (setq n (1- n))
0))
(list t1 (current-time-string))))
=> silly-loop
(silly-loop 100000)
=> ("Thu Jan 12 20:18:38 1989"
"Thu Jan 12 20:19:29 1989") ; 51 seconds
(byte-compile 'silly-loop)
=> [Compiled code not shown]
(silly-loop 100000)
=> ("Thu Jan 12 20:21:04 1989"
"Thu Jan 12 20:21:17 1989") ; 13 seconds
In this example, the interpreted code required 51 seconds to run,
whereas the byte-compiled code required 13 seconds. These results are
representative, but actual results will vary greatly.
- Function: byte-compile SYMBOL
This function byte-compiles the function definition of SYMBOL,
replacing the previous definition with the compiled one. The
function definition of SYMBOL must be the actual code for the
function; i.e., the compiler does not follow indirection to
another symbol. `byte-compile' does not compile macros.
`byte-compile' returns the new, compiled definition of SYMBOL.
(defun factorial (integer)
"Compute factorial of INTEGER."
(if (= 1 integer) 1
(* integer (factorial (1- integer)))))
=> factorial
(byte-compile 'factorial)
=>
#[(integer)
"^H\301U\203^H^@\301\207\302^H\303^HS!\"\207"
[integer 1 * factorial]
4 "Compute factorial of INTEGER."]
The result is a compiled function object. The string it contains
is the actual byte-code; each character in it is an instruction.
The vector contains all the constants, variable names and function
names used by the function, except for certain primitives that are
coded as special instructions.
- Command: compile-defun
This command reads the defun containing point, compiles it, and
evaluates the result. If you use this on a defun that is actually
a function definition, the effect is to install a compiled version
of that function.
- Command: byte-compile-file FILENAME
This function compiles a file of Lisp code named FILENAME into a
file of byte-code. The output file's name is made by appending
`c' to the end of FILENAME.
Compilation works by reading the input file one form at a time.
If it is a definition of a function or macro, the compiled
function or macro definition is written out. Other forms are
batched together, then each batch is compiled, and written so that
its compiled code will be executed when the file is read. All
comments are discarded when the input file is read.
This command returns `t'. When called interactively, it prompts
for the file name.
% ls -l push*
-rw-r--r-- 1 lewis 791 Oct 5 20:31 push.el
(byte-compile-file "~/emacs/push.el")
=> t
% ls -l push*
-rw-r--r-- 1 lewis 791 Oct 5 20:31 push.el
-rw-rw-rw- 1 lewis 638 Oct 8 20:25 push.elc
- Command: byte-recompile-directory DIRECTORY FLAG
This function recompiles every `.el' file in DIRECTORY that needs
recompilation. A file needs recompilation if a `.elc' file exists
but is older than the `.el' file.
If a `.el' file exists, but there is no corresponding `.elc' file,
then FLAG is examined. If it is `nil', the file is ignored. If
it is non-`nil', the user is asked whether the file should be
compiled.
The returned value of this command is unpredictable.
- Function: batch-byte-compile
This function runs `byte-compile-file' on the files remaining on
the command line. This function must be used only in a batch
execution of Emacs, as it kills Emacs on completion. An error in
one file does not prevent processing of subsequent files. (The
file which gets the error will not, of course, produce any
compiled code.)
% emacs -batch -f batch-byte-compile *.el
- Function: byte-code CODE-STRING DATA-VECTOR MAX-STACK
This function actually interprets byte-code. A byte-compiled
function is actually defined with a body that calls `byte-code'.
Don't call this function yourself. Only the byte compiler knows
how to generate valid calls to this function.
In newer Emacs versions (19 and up), byte-code is usually executed
as part of a compiled function object, and only rarely as part of
a call to `byte-code'.
File: elisp, Node: Eval During Compile, Next: Byte-Code Objects, Prev: Compilation Functions, Up: Byte Compilation
Evaluation During Compilation
=============================
These features permit you to write code to be evaluated during
compilation of a program.
- Special Form: eval-and-compile BODY
This form marks BODY to be evaluated both when you compile the
containing code and when you run it (whether compiled or not).
You can get a similar result by putting BODY in a separate file
and referring to that file with `require'. Using `require' is
preferable if there is a substantial amount of code to be executed
in this way.
- Special Form: eval-when-compile BODY
This form marks BODY to be evaluated at compile time *only*. The
result of evaluation by the compiler becomes a constant which
appears in the compiled program. When the program is interpreted,
not compiled at all, BODY is evaluated normally.
At top-level, this is analogous to the Common Lisp idiom
`(eval-when (compile) ...)'. Elsewhere, the Common Lisp `#.'
reader macro (but not when interpreting) is closer to what
`eval-when-compile' does.
File: elisp, Node: Byte-Code Objects, Next: Disassembly, Prev: Eval During Compile, Up: Byte Compilation
Byte-Code Objects
=================
Byte-compiled functions have a special data type: they are
"byte-code function objects".
Internally, a byte-code function object is much like a vector;
however, the evaluator handles this data type specially when it appears
as a function to be called. The printed representation for a byte-code
function object is like that for a vector, with an additional `#'
before the opening `['.
In Emacs version 18, there was no byte-code function object data
type; compiled functions used the function `byte-code' to run the byte
code.
A byte-code function object must have at least four elements; there
is no maximum number, but only the first six elements are actually used.
They are:
ARGLIST
The list of argument symbols.
BYTE-CODE
The string containing the byte-code instructions.
CONSTANTS
The vector of constants referenced by the byte code.
STACKSIZE
The maximum stack size this function needs.
DOCSTRING
The documentation string (if any); otherwise, `nil'. For functions
preloaded before Emacs is dumped, this is usually an integer which
is an index into the `DOC' file; use `documentation' to convert
this into a string (*note Accessing Documentation::.).
INTERACTIVE
The interactive spec (if any). This can be a string or a Lisp
expression. It is `nil' for a function that isn't interactive.
Here's an example of a byte-code function object, in printed
representation. It is the definition of the command `backward-sexp'.
#[(&optional arg)
"^H\204^F^@\301^P\302^H[!\207"
[arg 1 forward-sexp]
2
254435
"p"]
The primitive way to create a byte-code object is with
`make-byte-code':
- Function: make-byte-code &rest ELEMENTS
This function constructs and returns a byte-code function object
with ELEMENTS as its elements.
You should not try to come up with the elements for a byte-code
function yourself, because if they are inconsistent, Emacs may crash
when you call the function. Always leave it to the byte-compiler to
create these objects; it, we hope, always makes the elements consistent.
You can access the elements of a byte-code object using `aref'; you
can also use `vconcat' to create a vector with the same elements.
File: elisp, Node: Disassembly, Prev: Byte-Code Objects, Up: Byte Compilation
Disassembled Byte-Code
======================
People do not write byte-code; that job is left to the byte compiler.
But we provide a disassembler to satisfy a cat-like curiosity. The
disassembler converts the byte-compiled code into humanly readable form.
The byte-code interpreter is implemented as a simple stack machine.
Values get stored by being pushed onto the stack, and are popped off and
manipulated, the results being pushed back onto the stack. When a
function returns, the top of the stack is popped and returned as the
value of the function.
In addition to the stack, values used during byte-code execution can
be stored in ordinary Lisp variables. Variable values can be pushed
onto the stack, and variables can be set by popping the stack.
- Command: disassemble OBJECT &optional STREAM
This function prints the disassembled code for OBJECT. If STREAM
is supplied, then output goes there. Otherwise, the disassembled
code is printed to the stream `standard-output'. The argument
OBJECT can be a function name or a lambda expression.
As a special exception, if this function is used interactively, it
outputs to a buffer named `*Disassemble*'.
Here are two examples of using the `disassemble' function. We have
added explanatory comments to help you relate the byte-code to the Lisp
source; these do not appear in the output of `disassemble'. These
examples show unoptimized byte-code. Nowadays byte-code is usually
optimized, but we did not want to rewrite these examples, since they
still serve their purpose.
(defun factorial (integer)
"Compute factorial of an integer."
(if (= 1 integer) 1
(* integer (factorial (1- integer)))))
=> factorial
(factorial 4)
=> 24
(disassemble 'factorial)
-| byte-code for factorial:
doc: Compute factorial of an integer.
args: (integer)
0 constant 1 ; Push 1 onto stack.
1 varref integer ; Get value of `integer'
; from the environment
; and push the value
; onto the stack.
2 eqlsign ; Pop top two values off stack,
; compare them,
; and push result onto stack.
3 goto-if-nil 10 ; Pop and test top of stack;
; if `nil', go to 10,
; else continue.
6 constant 1 ; Push 1 onto top of stack.
7 goto 17 ; Go to 17 (in this case, 1 will be
; returned by the function).
10 constant * ; Push symbol `*' onto stack.
11 varref integer ; Push value of `integer' onto stack.
12 constant factorial ; Push `factorial' onto stack.
13 varref integer ; Push value of `integer' onto stack.
14 sub1 ; Pop `integer', decrement value,
; push new value onto stack.
; Stack now contains:
; - decremented value of `integer'
; - `factorial'
; - value of `integer'
; - `*'
15 call 1 ; Call function `factorial' using
; the first (i.e., the top) element
; of the stack as the argument;
; push returned value onto stack.
; Stack now contains:
; - result of result of recursive
; call to `factorial'
; - value of `integer'
; - `*'
16 call 2 ; Using the first two
; (i.e., the top two)
; elements of the stack
; as arguments,
; call the function `*',
; pushing the result onto the stack.
17 return ; Return the top element
; of the stack.
=> nil
The `silly-loop' function is somewhat more complex:
(defun silly-loop (n)
"Return time before and after N iterations of a loop."
(let ((t1 (current-time-string)))
(while (> (setq n (1- n))
0))
(list t1 (current-time-string))))
=> silly-loop
(disassemble 'silly-loop)
-| byte-code for silly-loop:
doc: Return time before and after N iterations of a loop.
args: (n)
0 constant current-time-string ; Push
; `current-time-string'
; onto top of stack.
1 call 0 ; Call `current-time-string'
; with no argument,
; pushing result onto stack.
2 varbind t1 ; Pop stack and bind `t1'
; to popped value.
3 varref n ; Get value of `n' from
; the environment and push
; the value onto the stack.
4 sub1 ; Subtract 1 from top of stack.
5 dup ; Duplicate the top of the stack;
; i.e. copy the top of
; the stack and push the
; copy onto the stack.
6 varset n ; Pop the top of the stack,
; and bind `n' to the value.
; In effect, the sequence `dup varset'
; copies the top of the stack
; into the value of `n'
; without popping it.
7 constant 0 ; Push 0 onto stack.
8 gtr ; Pop top two values off stack,
; test if N is greater than 0
; and push result onto stack.
9 goto-if-nil-else-pop 17 ; Goto 17 if `n' > 0
; else pop top of stack
; and continue
; (this exits the while loop).
12 constant nil ; Push `nil' onto stack
; (this is the body of the loop).
13 discard ; Discard result of the body
; of the loop (a while loop
; is always evaluated for
; its side effects).
14 goto 3 ; Jump back to beginning
; of while loop.
17 discard ; Discard result of while loop
; by popping top of stack.
18 varref t1 ; Push value of `t1' onto stack.
19 constant current-time-string ; Push
; `current-time-string'
; onto top of stack.
20 call 0 ; Call `current-time-string' again.
21 list2 ; Pop top two elements off stack,
; create a list of them,
; and push list onto stack.
22 unbind 1 ; Unbind `t1' in local environment.
23 return ; Return value of the top of stack.
=> nil
File: elisp, Node: Debugging, Next: Streams, Prev: Byte Compilation, Up: Top
Debugging Lisp Programs
***********************
There are three ways to investigate a problem in an Emacs Lisp
program, depending on what you are doing with the program when the
problem appears.
* If the problem occurs when you run the program, you can use the
Lisp debugger to investigate what is happening during execution.
* If the problem is syntactic, so that Lisp cannot even read the
program, you can use the Emacs facilities for editing Lisp to
localize it.
* If the problem occurs when trying to compile the program with the
byte compiler, you need to know how to examine the compiler's
input buffer.
* Menu:
* Debugger:: How the Emacs Lisp debugger is implemented.
* Syntax Errors:: How to find syntax errors.
* Compilation Errors:: How to find errors that show up in byte compilation.
* Edebug:: A source-level Emacs Lisp debugger.
Another useful debugging tool is a dribble file. When a dribble file
is open, Emacs copies all keyboard input characters to that file.
Afterward, you can examine the file to find out what input was used.
*Note Terminal Input::.
For debugging problems in terminal descriptions, the
`open-termscript' function can be useful. *Note Terminal Output::.
File: elisp, Node: Debugger, Next: Syntax Errors, Up: Debugging
The Lisp Debugger
=================
The "Lisp debugger" provides you with the ability to suspend
evaluation of a form. While evaluation is suspended (a state that is
commonly known as a "break"), you may examine the run time stack,
examine the values of local or global variables, or change those values.
Since a break is a recursive edit, all the usual editing facilities of
Emacs are available; you can even run programs that will enter the
debugger recursively. *Note Recursive Editing::.
* Menu:
* Error Debugging:: Entering the debugger when an error happens.
* Infinite Loops:: Stopping and debugging a program that doesn't exit.
* Function Debugging:: Entering it when a certain function is called.
* Explicit Debug:: Entering it at a certain point in the program.
* Using Debugger:: What the debugger does; what you see while in it.
* Debugger Commands:: Commands used while in the debugger.
* Invoking the Debugger:: How to call the function `debug'.
* Internals of Debugger:: Subroutines of the debugger, and global variables.
File: elisp, Node: Error Debugging, Next: Infinite Loops, Up: Debugger
Entering the Debugger on an Error
---------------------------------
The most important time to enter the debugger is when a Lisp error
happens. This allows you to investigate the immediate causes of the
error.
However, entry to the debugger is not a normal consequence of an
error. Many commands frequently get Lisp errors when invoked in
inappropriate contexts (such as `C-f' at the end of the buffer) and
during ordinary editing it would be very unpleasant to enter the
debugger each time this happens. If you want errors to enter the
debugger, set the variable `debug-on-error' to non-`nil'.
- User Option: debug-on-error
This variable determines whether the debugger is called when a
error is signaled and not handled. If `debug-on-error' is `t', all
errors call the debugger. If it is `nil', none call the debugger.
The value can also be a list of error conditions that should call
the debugger. For example, if you set it to the list
`(void-variable)', then only errors about a variable that has no
value invoke the debugger.
File: elisp, Node: Infinite Loops, Next: Function Debugging, Prev: Error Debugging, Up: Debugger
Debugging Infinite Loops
------------------------
When a program loops infinitely and fails to return, your first
problem is to stop the loop. On most operating systems, you can do this
with `C-g', which causes quit.
Ordinary quitting gives no information about why the program was
looping. To get more information, you can set the variable
`debug-on-quit' to non-`nil'. Quitting with `C-g' is not considered an
error, and `debug-on-error' has no effect on the handling of `C-g'.
Contrariwise, `debug-on-quit' has no effect on errors.
Once you have the debugger running in the middle of the infinite
loop, you can proceed from the debugger using the stepping commands.
If you step through the entire loop, you will probably get enough
information to solve the problem.
- User Option: debug-on-quit
This variable determines whether the debugger is called when `quit'
is signaled and not handled. If `debug-on-quit' is non-`nil',
then the debugger is called whenever you quit (that is, type
`C-g'). If `debug-on-quit' is `nil', then the debugger is not
called when you quit. *Note Quitting::.
File: elisp, Node: Function Debugging, Next: Explicit Debug, Prev: Infinite Loops, Up: Debugger
Entering the Debugger on a Function Call
----------------------------------------
To investigate a problem that happens in the middle of a program, one
useful technique is to cause the debugger to be entered when a certain
function is called. You can do this to the function in which the
problem occurs, and then step through the function, or you can do this
to a function called shortly before the problem, step quickly over the
call to that function, and then step through its caller.
- Command: debug-on-entry FUNCTION-NAME
This function requests FUNCTION-NAME to invoke the debugger each
time it is called. It works by inserting the form `(debug
'debug)' into the function definition as the first form.
Any function defined as Lisp code may be set to break on entry,
regardless of whether it is interpreted code or compiled code.
Even functions that are commands may be debugged--they will enter
the debugger when called inside a function, or when called
interactively (after the reading of the arguments). Primitive
functions (i.e., those written in C) may not be debugged.
When `debug-on-entry' is called interactively, it prompts for
FUNCTION-NAME in the minibuffer.
Caveat: if `debug-on-entry' is called more than once on the same
function, the second call does nothing. If you redefine a function
after using `debug-on-entry' on it, the code to enter the debugger
is lost.
`debug-on-entry' returns FUNCTION-NAME.
(defun fact (n)
(if (zerop n) 1
(* n (fact (1- n)))))
=> fact
(debug-on-entry 'fact)
=> fact
(fact 3)
=> 6
------ Buffer: *Backtrace* ------
Entering:
* fact(3)
eval-region(4870 4878 t)
byte-code("...")
eval-last-sexp(nil)
(let ...)
eval-insert-last-sexp(nil)
* call-interactively(eval-insert-last-sexp)
------ Buffer: *Backtrace* ------
(symbol-function 'fact)
=> (lambda (n)
(debug (quote debug))
(if (zerop n) 1 (* n (fact (1- n)))))
- Command: cancel-debug-on-entry FUNCTION-NAME
This function undoes the effect of `debug-on-entry' on
FUNCTION-NAME. When called interactively, it prompts for
FUNCTION-NAME in the minibuffer.
If `cancel-debug-on-entry' is called more than once on the same
function, the second call does nothing. `cancel-debug-on-entry'
returns FUNCTION-NAME.
File: elisp, Node: Explicit Debug, Next: Using Debugger, Prev: Function Debugging, Up: Debugger
Explicit Entry to the Debugger
------------------------------
You can cause the debugger to be called at a certain point in your
program by writing the expression `(debug)' at that point. To do this,
visit the source file, insert the text `(debug)' at the proper place,
and type `C-M-x'. Be sure to undo this insertion before you save the
file!
The place where you insert `(debug)' must be a place where an
additional form can be evaluated and its value ignored. (If the value
isn't ignored, it will alter the execution of the program!) Usually
this means inside a `progn' or an implicit `progn' (*note
Sequencing::.).
File: elisp, Node: Using Debugger, Next: Debugger Commands, Prev: Explicit Debug, Up: Debugger
Using the Debugger
------------------
When the debugger is entered, it displays the previously selected
buffer in one window and a buffer named `*Backtrace*' in another
window. The backtrace buffer contains one line for each level of Lisp
function execution currently going on. At the beginning of this buffer
is a message describing the reason that the debugger was invoked (such
as the error message and associated data, if it was invoked due to an
error).
The backtrace buffer is read-only and uses a special major mode,
Debugger mode, in which letters are defined as debugger commands. The
usual Emacs editing commands are available; thus, you can switch windows
to examine the buffer that was being edited at the time of the error,
switch buffers, visit files, or do any other sort of editing. However,
the debugger is a recursive editing level (*note Recursive Editing::.)
and it is wise to go back to the backtrace buffer and exit the debugger
(with the `q' command) when you are finished with it. Exiting the
debugger gets out of the recursive edit and kills the backtrace buffer.
The contents of the backtrace buffer show you the functions that are
executing and the arguments that were given to them. It also allows
you to specify a stack frame by moving point to the line describing
that frame. (A stack frame is the place where the Lisp interpreter
records information about a particular invocation of a function. The
frame whose line point is on is considered the "current frame".) Some
of the debugger commands operate on the current frame.
The debugger itself should always be run byte-compiled, since it
makes assumptions about how many stack frames are used for the debugger
itself. These assumptions are false if the debugger is running
interpreted.
File: elisp, Node: Debugger Commands, Next: Invoking the Debugger, Prev: Using Debugger, Up: Debugger
Debugger Commands
-----------------
Inside the debugger (in Debugger mode), these special commands are
available in addition to the usual cursor motion commands. (Keep in
mind that all the usual facilities of Emacs, such as switching windows
or buffers, are still available.)
The most important use of debugger commands is for stepping through
code, so that you can see how control flows. The debugger can step
through the control structures of an interpreted function, but cannot do
so in a byte-compiled function. If you would like to step through a
byte-compiled function, replace it with an interpreted definition of the
same function. (To do this, visit the source file for the function and
type `C-M-x' on its definition.)
Exit the debugger and continue execution. When continuing is
possible, it resumes execution of the program as if the debugger
had never been entered (aside from the effect of any variables or
data structures you may have changed while inside the debugger).
Continuing is possible after entry to the debugger due to function
entry or exit, explicit invocation, quitting or certain errors.
Most errors cannot be continued; trying to continue an unsuitable
error causes the same error to occur again.
Continue execution, but enter the debugger the next time any Lisp
function is called. This allows you to step through the
subexpressions of an expression, seeing what values the
subexpressions compute, and what else they do.
The stack frame made for the function call which enters the
debugger in this way will be flagged automatically so that the
debugger will be called again when the frame is exited. You can
use the `u' command to cancel this flag.
Flag the current frame so that the debugger will be entered when
the frame is exited. Frames flagged in this way are marked with
stars in the backtrace buffer.
Don't enter the debugger when the current frame is exited. This
cancels a `b' command on that frame.
Read a Lisp expression in the minibuffer, evaluate it, and print
the value in the echo area. This is the same as the command
`M-ESC', except that `e' is not normally disabled like `M-ESC'.
Terminate the program being debugged; return to top-level Emacs
command execution.
If the debugger was entered due to a `C-g' but you really want to
quit, and not debug, use the `q' command.
Return a value from the debugger. The value is computed by
reading an expression with the minibuffer and evaluating it.
The `r' command makes a difference when the debugger was invoked
due to exit from a Lisp call frame (as requested with `b'); then
the value specified in the `r' command is used as the value of that
frame.
You can't use `r' when the debugger was entered due to an error.
File: elisp, Node: Invoking the Debugger, Next: Internals of Debugger, Prev: Debugger Commands, Up: Debugger
Invoking the Debugger
---------------------
Here we describe fully the function used to invoke the debugger.
- Function: debug &rest DEBUGGER-ARGS
This function enters the debugger. It switches buffers to a buffer
named `*Backtrace*' (or `*Backtrace*<2>' if it is the second
recursive entry to the debugger, etc.), and fills it with
information about the stack of Lisp function calls. It then
enters a recursive edit, leaving that buffer in Debugger mode and
displayed in the selected window.
Debugger mode provides a `c' command which operates by exiting the
recursive edit, switching back to the previous buffer, and
returning to whatever called `debug'. The `r' command also
returns from `debug'. These are the only ways the function
`debug' can return to its caller.
If the first of the DEBUGGER-ARGS passed to `debug' is `nil' (or
if it is not one of the following special values), then the rest
of the arguments to `debug' are printed at the top of the
`*Backtrace*' buffer. This mechanism is used to display a message
to the user.
However, if the first argument passed to `debug' is one of the
following special values, then it has special significance.
Normally, these values are passed to `debug' only by the internals
of Emacs and the debugger, and not by programmers calling `debug'.
The special values are:
`lambda'
When the first argument is `lambda', the debugger displays
`Entering:' as a line of text at the top of the buffer. This
means that a function is being entered when
`debug-on-next-call' is non-`nil'.
`debug'
When the first argument is `debug', the debugger displays
`Entering:' just as in the `lambda' case. However, `debug'
as the argument indicates that the reason for entering the
debugger is that a function set to debug on entry is being
entered.
In addition, `debug' as the first argument directs the
debugger to mark the function that called `debug' so that it
will invoke the debugger when exited. (When `lambda' is the
first argument, the debugger does not do this, because it has
already been done by the interpreter.)
`t'
When the first argument is `t', the debugger displays the
following as the top line in the buffer:
Beginning evaluation of function call form:
This indicates that it was entered due to the evaluation of a
list form at a time when `debug-on-next-call' is non-`nil'.
`exit'
When the first argument is `exit', it indicates the exit of a
stack frame previously marked to invoke the debugger on exit.
The second argument given to `debug' in this case is the
value being returned from the frame. The debugger displays
`Return value:' on the top line of the buffer, followed by
the value being returned.
`error'
When the first argument is `error', the debugger indicates
that it is being entered because an error or `quit' was
signaled and not handled, by displaying `Signaling:' followed
by the error signaled and any arguments to `signal'. For
example,
(let ((debug-on-error t))
(/ 1 0))
------ Buffer: *Backtrace* ------
Signaling: (arith-error)
/(1 0)
...
------ Buffer: *Backtrace* ------
If an error was signaled, presumably the variable
`debug-on-error' is non-`nil'. If `quit' was signaled, then
presumably the variable `debug-on-quit' is non-`nil'.
`nil'
Use `nil' as the first of the DEBUGGER-ARGS when you want to
enter the debugger explicitly. The rest of the DEBUGGER-ARGS
are printed on the top line of the buffer. You can use this
feature to display messages--for example, to remind yourself
of the conditions under which `debug' is called.
File: elisp, Node: Internals of Debugger, Prev: Invoking the Debugger, Up: Debugger
Internals of the Debugger
-------------------------
This section describes functions and variables used internally by the
debugger.
- Variable: debugger
The value of this variable is the function to call to invoke the
debugger. Its value must be a function of any number of arguments
(or, more typically, the name of a function). Presumably this
function will enter some kind of debugger. The default value of
the variable is `debug'.
The first argument that Lisp hands to the function indicates why it
was called. The convention for arguments is detailed in the
description of `debug'.
- Command: backtrace
This function prints a trace of Lisp function calls currently
active. This is the function used by `debug' to fill up the
`*Backtrace*' buffer. It is written in C, since it must have
access to the stack to determine which function calls are active.
The return value is always `nil'.
In the following example, `backtrace' is called explicitly in a
Lisp expression. When the expression is evaluated, the backtrace
is printed to the stream `standard-output': in this case, to the
buffer `backtrace-output'. Each line of the backtrace represents
one function call. If the arguments of the function call are all
known, they are displayed; if they are being computed, that fact
is stated. The arguments of special forms are elided.
(with-output-to-temp-buffer "backtrace-output"
(let ((var 1))
(save-excursion
(setq var (eval '(progn
(1+ var)
(list 'testing (backtrace))))))))
=> nil
----------- Buffer: backtrace-output ------------
backtrace()
(list ...computing arguments...)
(progn ...)
eval((progn (1+ var) (list (quote testing) (backtrace))))
(setq ...)
(save-excursion ...)
(let ...)
(with-output-to-temp-buffer ...)
eval-region(1973 2142 #<buffer *scratch*>)
byte-code("... for eval-print-last-sexp ...")
eval-print-last-sexp(nil)
* call-interactively(eval-print-last-sexp)
----------- Buffer: backtrace-output ------------
The character `*' indicates a frame whose debug-on-exit flag is
set.
- Variable: debug-on-next-call
This variable determines whether the debugger is called before the
next `eval', `apply' or `funcall'. It is automatically reset to
`nil' when the debugger is entered.
The `d' command in the debugger works by setting this variable.
- Function: backtrace-debug LEVEL FLAG
This function sets the debug-on-exit flag of the eval frame LEVEL
levels down to FLAG. If FLAG is non-`nil', this will cause the
debugger to be entered when that frame exits. Even a nonlocal
exit through that frame will enter the debugger.
The debug-on-exit flag is an entry in the stack frame of a
function call. This flag is examined on every exit from a
function.
Normally, this function is only called by the debugger.
- Variable: command-debug-status
This variable records the debugging status of current interactive
command. Each time a command is called interactively, this
variable is bound to `nil'. The debugger can set this variable to
leave information for future debugger invocations during the same
command.
The advantage of using this variable rather that defining another
global variable is that the data will never carry over to a later
other command invocation.
- Function: backtrace-frame FRAME-NUMBER
The function `backtrace-frame' is intended for use in Lisp
debuggers. It returns information about what computation is
happening in the eval frame LEVEL levels down.
If that frame has not evaluated the arguments yet (or is a special
form), the value is `(nil FUNCTION ARG-FORMS...)'.
If that frame has evaluated its arguments and called its function
already, the value is `(t FUNCTION ARG-VALUES...)'.
In the return value, FUNCTION is whatever was supplied as CAR of
evaluated list, or a `lambda' expression in the case of a macro
call. If the function has a `&rest' argument, that is represented
as the tail of the list ARG-VALUES.
If the argument is out of range, `backtrace-frame' returns `nil'.